Re: Action for emailing to a specific person?

null@example.com (John) — Thu, 23 Apr 2026 23:19:49 +0000

If you use the built-in macOS Mail app then you can add a 'Run AppleScript' action with the following code. You need to set it to handles 'Dragged Files' when configuring the action.

Also, note that this sends the email immediately when dragging files onto the action so make sure you update the recipient address at the top before using it:

set recipient_address to "recipient@example.com"
set email_subject to ""
set email_body to ""

set all_attachments to {}

repeat with i from 1 to number of items in draggedFiles
    set draggedFile to item i of draggedFiles
    set the_attachment to POSIX path of draggedFile
    set end of all_attachments to the_attachment
end repeat

tell application "Mail"
    activate
    set new_message to make new outgoing message with properties {subject:email_subject, visible:true}
    tell new_message
        make new to recipient at end of to recipients with properties {address:recipient_address}
        set content to email_body
        repeat with the_attachment in all_attachments
            make new attachment with properties {file name:the_attachment} at after the last paragraph
        end repeat
    end tell
    send new_message
end tell

Action for emailing to a specific person?

null@example.com (markwallac@gmail.com) — Thu, 23 Apr 2026 16:00:24 +0000

I have a recurring need to email stuff (file attachments and/or text) from my personal email address to my work address.

I have Dropzone 5 installed on my personal Mac. Is there (or could there be) a Dropzone action that would let me drop something (file or text) into the grid and that it would automatically just email it to my work address? It would be the same fixed email address all the time.

Thank you!

Mark

Dropzone Forums — Action for emailing to a specific person?

Re: Action for emailing to a specific person?

Action for emailing to a specific person?